TannieSpace

I use OmniFocus a lot, and have recently tweaked some more AppleScripts to make my workflow even more smooth. I can add any mail to OmniFocus for replies, add confirmation of orders from mail to OmniFocus which will automatically go into my project-shoebox for orders, with a 'waiting for' context and a due date set to 1 week into the future, unless I've changed or added MailTags with a project, a keyword and a due date. In that case it'll take the project, the first keyword and the due date and use them to set up the OmniFocus task. I have a few more scripts:

• in OmniWeb I can take and add a URL for later reading, it'll go into my inbox by default
• in OmniWeb I can take and add a URL to my 'wish-list' project (with a start date for at 2 weeks in the future)
• in OmniFocus I have scripts to easily change the context or the project of selected tasks
• in Mail I can press a key and have the selected e-mail(s) sent to OmniFocus with a 'Respond to: ' before the subject line, sorting into either a default project or the one specified in MailTags, with the context set to 'mail' and the message URL in the note-field
• in OmniFocus I can select such a task, press a key to run a script that will open the message and immediately create a reply (I have a separate one for just opening, in case I have to read it thoroughly first)

All these scripts make the integration between all these programs very easy. That and FastScripts. I found useful scripts over at Curtis Clifton's site. His scripts use Growl notification so if you have Growl installed you get a small notification.

I had some trouble putting my own scripts together, so I decided to paste the info here, just in case I need it later on, or someone else runs into similar issues. I found it quite hard to figure out how to add a task to an existing project or to move it from inbox / other project. In the end, it only took a few lines.

First, when I started my script, I wanted a default project or context (I'll use 'project' from now on, but it also applies to the context-script). To do this I created a 'property' at the beginning of the script:

property defaultProject : "Miscellaneous" property alertItemNum : ""

I used the alterItemNum for my alerts through this very simple routine:

on notify(alertName, alertTitle, alertText) display dialog alertText as string with icon 1 end notify

That went at the end of my script.

I started by addressing OmniFocus and 'talking' to the open document:

tell application "OmniFocus" tell front document tell (first document window whose index is 1)

Then, I checked to see if that document had anything selected, and if not, give an error-dialogue:

            set theSelectedItems to selected trees of content
            set numItems to (count items of theSelectedItems)
            if numItems is 0 then
                set alertName to "Error"
                set alertTitle to "Script failure"
                set alertText to "No valid task(s) selected"
                my notify(alertName, alertTitle, alertText)
                return
            end if

If I have no items selected, the script will call the alert routine from above ( my notify(alertName, alertTitle, alertText) ). Because I created a separate routine, I can use this anywhere in the script.

Next, display a dialogue asking for the project: ` display dialog "Change to what Project? " default answer defaultProject buttons {"Cancel", "OK"} default button 2

set theProject to (the text returned of the result) ` The variable 'theProject' will now contain the name of the (new) project to move the tasks too.

Next, the loop to go through all the items and move them:

            set selectNum to numItems
            set successTot to 0
            repeat while selectNum > 0
                set selectedItem to value of item selectNum of theSelectedItems
                set succeeded to my ChangeProject(selectedItem, theProject)
                if succeeded then set successTot to successTot + 1
                set selectNum to selectNum - 1
            end repeat

This loop will end as soon as the variable 'selectNum' (= numItems which I set to the count of the items in the variable SelectedItems) reaches 0. It calls the routine 'ChangeProject' which I'll get to in a bit, but I first want to wrap up this part. Let me also explain the 'if succeeded then set successTot to successTot + 1' line. The line before sets 'succeeded' to the result of the ChangeProject routine. This result can mean anything, numbers, letters, whatever. In this case we use it to return a 'true' or 'false'. That way, we only need to use 'if succeeded' (which will either be 'true' or 'false') as a condition. We don't need to check the actual content of the variable. This can come in handy for various checks, and it took me a while to catch on to that, so I figured I'd mention it here.

To end this main routine, I used:

            set alertName to "General" set alertTitle to "Script complete"
            if successTot > 1 then set alertItemNum to "s"
            set alertText to successTot & " item" & alertItemNum & " changed to Project " & theProject
        end tell
    end tell
    my notify(alertName, alertTitle, alertText)
end tell

Basically, this tells the dialogue box to say the script ran successfully and displays the number of items successfully moved and only to use the 's' after 'item' if the count of successful moves is higher than 1.

That wraps up the main part.

The routine to actually move the task to the other project only took 21 lines:

on ChangeProject(selectedItem, theProject)
    set success to false
    tell application "OmniFocus" to tell default document
        if (theProject is not "") then
            set MyProjectArray to null
            set MyProjectArray to complete theProject as project maximum matches 1
            try
                set MyProjectID to id of first item of MyProjectArray
                set theNewProject to project id MyProjectID
            on error
                set theNewProject to (make project with properties {name:theProject})
            end try

            try
                set newtask to selectedItem
                move newtask to end of tasks of theNewProject
                set success to true
            end try
        end if
    end tell
    return success
end ChangeProject

The first line sets the success to 'false', because we want to actively, after having our success, set it to 'true'. We then chat with OmniFocus again, and this time, we'll just talk to the default document (the one you have open). If the variable 'theProject' is not empty, we'll continue. If it is, the 'if-end if' ends, without having set the 'success' variable to true (and thus, the script failed). You could technically build in an extra loop to change it to a default project, however, I prefer it this way. If I accidentally emptied that dialogue-box, nothing will happen, just as I like it.

If theProject does contain something (anything), the script continues with its routine. It sets the MyProjectArray to null (makes it empty, just in case). It then used OmniFocus complete option to find the first matching project of OmniFocuses project-list. If you've ever only typed the first three letters in one of OmniFocus's project-areas (to set the project) and it magically came up with the right project, this is the same thing. It means you only have to type the first three or four letters of your project, and the script will find it. If it can't find the project, it will create it for you (at the end of your project-list).

After that, it will simply try to add the task to the desired project.